home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
pc
/
LOGIC Apple II 5.25" Library - DOS Part 3
/
DOS078A.dsk
/
TEXT FILE CHAR HEX DUMP.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
1KB
|
43 lines
100 D$ = CHR$(4):R$ = CHR$(13)
200 BS$ = CHR$(8)
300 H$ = "0123456789ABCDEF"
400 TEXT : INVERSE
410 PRINT : PRINT "CHARACTER+HEX DUMP OF TEXT FIL<CTRL-V>ES"
500 PRINT
600 INPUT "INPUT FILE:";F$
700 PRINT : INPUT "HOW MANY RECORDS ?";X$
800 IF X$ = "ALL" THEN RM = 1E10: GOTO 1000
900 RM = VAL(X$)
1000 HOME :RN = 0
1100 PRINT D$;"OPEN";F$
1200 PRINT D$;"READ";F$
1300 ONERR GOTO 3300
1400 RN = RN +1:A$ = ""
1500 IF RN >RM THEN 3600
1600 GET X$:A$ = A$ +X$
1700 IF X$ < >R$ THEN 1600
1800 AL = LEN(A$)
1900 PRINT " RECORD ";RN;" LRECL=";AL
2000 W = 0
2100 FOR I = 1 TO AL STEP 40
2200 C$ = "":HH$ = "":HL$ = ""
2210 T = AL -I: IF T >39 THEN T = 39
2300 FOR J = 0 TO T:K = I +J
2400 P$ = MID$ (A$,K,1):AP = ASC(P$)
2500 IF AP <32 OR AP >95 THEN C$ = C$ +" ": GOTO 2700
2600 C$ = C$ +P$
2700 HH = INT(AP/16):HL = AP -HH *16
2800 HH$ = HH$ + MID$ (H$,HH +1,1):HL$ = HL$ + MID$ (H$,HL +1,1)
2900 NEXT J
2910 IF LEN(C$) <40 THEN 3000
2920 PRINT C$;HH$;HL$: PRINT : GOTO 3100
3000 PRINT C$: PRINT HH$: PRINT HL$: PRINT
3100 NEXT I
3200 GOTO 1400
3300 POKE 216,0
3400 IF PEEK(222) = 5 THEN 3600
3500 PRINT "ERROR CODE="; PEEK(222);" AT "; PEEK(218) + PEEK(219) *256
3600 PRINT : PRINT D$;"CLOSE";F$
3700 END
4000 REM BRUCE W. CHRISTOPHER
4010 REM CHAR/HEX DUMP OF TXT FILES.