home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS078A.dsk / TEXT FILE CHAR HEX DUMP.bas < prev    next >
BASIC Source File  |  2012-02-16  |  1KB  |  43 lines
  1. 100 D$ =  CHR$(4):R$ =  CHR$(13)
  2. 200 BS$ =  CHR$(8)
  3. 300 H$ = "0123456789ABCDEF"
  4. 400  TEXT : INVERSE 
  5. 410  PRINT : PRINT "CHARACTER+HEX DUMP OF TEXT FIL<CTRL-V>ES"
  6. 500  PRINT 
  7. 600  INPUT "INPUT FILE:";F$
  8. 700  PRINT : INPUT "HOW MANY RECORDS ?";X$
  9. 800  IF X$ = "ALL"  THEN RM = 1E10: GOTO 1000
  10. 900 RM =  VAL(X$)
  11. 1000  HOME :RN = 0
  12. 1100  PRINT D$;"OPEN";F$
  13. 1200  PRINT D$;"READ";F$
  14. 1300  ONERR  GOTO 3300
  15. 1400 RN = RN +1:A$ = ""
  16. 1500  IF RN >RM  THEN 3600
  17. 1600  GET X$:A$ = A$ +X$
  18. 1700  IF X$ < >R$  THEN 1600
  19. 1800 AL =  LEN(A$)
  20. 1900  PRINT " RECORD ";RN;"  LRECL=";AL
  21. 2000 W = 0
  22. 2100  FOR I = 1 TO AL  STEP 40
  23. 2200 C$ = "":HH$ = "":HL$ = ""
  24. 2210 T = AL -I: IF T >39  THEN T = 39
  25. 2300  FOR J = 0 TO T:K = I +J
  26. 2400 P$ =  MID$ (A$,K,1):AP =  ASC(P$)
  27. 2500  IF AP <32  OR AP >95  THEN C$ = C$ +" ": GOTO 2700
  28. 2600 C$ = C$ +P$
  29. 2700 HH =  INT(AP/16):HL = AP -HH *16
  30. 2800 HH$ = HH$ + MID$ (H$,HH +1,1):HL$ = HL$ + MID$ (H$,HL +1,1)
  31. 2900  NEXT J
  32. 2910  IF  LEN(C$) <40  THEN 3000
  33. 2920  PRINT C$;HH$;HL$: PRINT : GOTO 3100
  34. 3000  PRINT C$: PRINT HH$: PRINT HL$: PRINT 
  35. 3100  NEXT I
  36. 3200  GOTO 1400
  37. 3300  POKE 216,0
  38. 3400  IF  PEEK(222) = 5  THEN 3600
  39. 3500  PRINT "ERROR CODE="; PEEK(222);" AT "; PEEK(218) + PEEK(219) *256
  40. 3600  PRINT : PRINT D$;"CLOSE";F$
  41. 3700  END 
  42. 4000  REM  BRUCE W. CHRISTOPHER
  43. 4010  REM  CHAR/HEX DUMP OF TXT FILES.